ABAP中的AMDP(ABAP-Managed Database Procedures )

ABAP管理下的数据库存储过程(ABAP-Managed Database
Procedure,以下简称AMDP)是于APAP on SAP
HANA开发被的一样栽优化模式。AMDP使用数据库语言书写,比如Native
SQL或者是SQL
Script,并且以AMDP类的AMDP方法外实现。因此用它们支付数据库存储过程尽管出接触类似于编辑ABAP类。

粗略,AMDP允许开发者直接当ABAP中描绘数据库存储过程。

 

本文链接:http://www.cnblogs.com/hhelibeb/p/7976533.html

转载请注明

缘何采取AMDP?

按SAP的官方建议,在可以用Open
SQL实现内需的功力要优化目标的上,不建议采用AMDP。而当待以Open
SQL不存的风味,或者是大气处理流和分析导致了数据库和应用服务器之间产生重的大量数据传的动静下,则该采用AMDP。

具体的例子可以看:AMDP, Comparison of SQLScript with Open
SQL
,

          SAP HANA, Currency Conversion with
SQLScript
   

AMDP还会提供以下好处:

  • SQL Script的静态代码检查
  • 语法高亮(支持pretty printer格式优化器) 
  • 以AMDP内访问其它AMDP方法、ABAP字典的视图和表 
  • 可以像一般的ABAP方法一致调用(不包括AMDP function)  
  • 使ST22进行运行时误的详细分析    

介绍视频:

语法

AMDP在AMDP类中实现,需要一个业内的静态方法或者实例方法,可见性任意:

CLASS <my_amdp_class> DEFINITION.

  PUBLIC SECTION.
* 指定的Marker接口
  INTERFACES IF_AMDP_MARKER_<DB_TYPE>.
   ...

  METHODS <my_amdp_method>.
   ...

ENDCLASS.


CLASS <my_amdp_class> IMPLEMENTATION.

...

* AMDP 方法 
  METHOD <my_amdp_method> BY DATABASE PROCEDURE 
        FOR <db_type>
        LANGUAGE <db_language>
         OPTIONS <db_options>  
         USING   <db_entity>.

      "使用数据库语言实现存储过程
     ...

  ENDMETHOD.
    ...

ENDCLASS.

AMDP类就是日常的切近,并落实IF_AMDP_MARKER_<DB_TYPE>接口。如果是HANA数据库,那么就算是实现接口IF_AMDP_MARKER_HDB。不过,虽然标准上AMDP是为着支持各种数据库的蕴藏过程要存在的,但到眼前(ABAP
7.52)为止,AMDP只支持SAP
HANA数据库。可以利用类似CL_ABAP_DBFEATURES屡遭之常量CALL_AMDP_METHOD来认可AMDP对时数据库的支持。

简单示例

示例类CL_DEMO_AMDP_SCARR绑定了接口IF_AMDP_MARKER_HDB,并且包含AMDP方法SELECT_SCARR来打表SCARR中获取数据(笔者目前未曾相应的条件,所以写了只ztest_amdp来取代示例):

CLASS ztest_amdp DEFINITION
  PUBLIC
  FINAL
  CREATE PUBLIC .

  PUBLIC SECTION.
    INTERFACES if_amdp_marker_hdb.
    CLASS-DATA: scarr_tab TYPE ty_scarr.
    METHODS select_scarr IMPORTING VALUE(clnt)      TYPE mandt
                         EXPORTING VALUE(scarr_tab) TYPE ty_scarr.
ENDCLASS.


CLASS ztest_amdp IMPLEMENTATION.
  METHOD select_scarr
         BY DATABASE PROCEDURE FOR HDB
         LANGUAGE SQLSCRIPT
         OPTIONS READ-ONLY
         USING scarr.
    scarr_tab =
    SELECT *
           FROM "SCARR"
           WHERE mandt = clnt
           ORDER BY carrid;
  ENDMETHOD.
ENDCLASS.

 

以下代码可以用来调用方法、获取结果:

DATA result TYPE ty_scarr.

NEW ztest_amdp( )->select_scarr(
  EXPORTING clnt = sy-mandt
  IMPORTING scarr_tab = result ).

cl_demo_output=>display( result ). 

AMDP方法

AMDP方法来一定量栽实现,一种植是AMDP
procedure心想事成;另一样种是AMDP
function实现。

AMDP procedure实现

得采用Method语句的叠加项BY DATABASE
PROCEDURE。例子见上文。这种实现方式写成的方式和平凡的ABAP对象方法以应用办法上尚未分别。

AMDP function实现

内需采取Method语句的附加项BY DATABASE
FUNCTION。它以AMDP方法实现呢一个table function。

tips: table function

  table function是只读的用户定义的方法,可以接收多个输入参数。接收单一的表返回值。

  在SQL Scitpt中,table function可以在与数据库表或者视图相同的位置使用。

 

演示代码:

REPORT demo_amdp_functions_inpcl.

CLASS demo DEFINITION.
  PUBLIC SECTION.
    CLASS-METHODS main.
ENDCLASS.

CLASS demo IMPLEMENTATION.
  METHOD main.
    IF NOT cl_abap_dbfeatures=>use_features(
          EXPORTING
            requested_features =
              VALUE #( ( cl_abap_dbfeatures=>call_amdp_method )
                       ( cl_abap_dbfeatures=>amdp_table_function ) ) ).
      cl_demo_output=>display(
        `System does not support AMDP or CDS table functions` ).
      RETURN.
    ENDIF.

    DATA carrid TYPE s_carr_id VALUE 'LH'.
    cl_demo_input=>request( CHANGING field = carrid ).
    carrid = to_upper( carrid ).

    "Database function selected in database procedure
    TRY.
        NEW cl_demo_amdp_functions_inpcl( )->select_get_scarr_spfli(
          EXPORTING clnt   = sy-mandt
                    carrid = carrid
          IMPORTING scarr_spfli_tab = DATA(result1) ).
      CATCH cx_amdp_error INTO DATA(amdp_error).
        cl_demo_output=>display( amdp_error->get_text( ) ).
        RETURN.
    ENDTRY.

    cl_demo_output=>display( result1 ).

  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  demo=>main( ).

 

上面这个例子访问的AMDP
function可以以类CL_DEMO_AMDP_FUNCTIONS_INPCL中看到。

方法GET_SCARR_SPFLI是一个AMDP
function实现,它是无能够直接在ABAP中访问的:

METHOD get_scarr_spfli BY DATABASE FUNCTION FOR HDB
                       LANGUAGE SQLSCRIPT
                       OPTIONS READ-ONLY
                       USING scarr spfli.
  RETURN SELECT sc.carrname, sp.connid, sp.cityfrom, sp.cityto
                FROM scarr AS sc
                  INNER JOIN spfli AS sp ON sc.mandt = sp.mandt AND
                                            sc.carrid = sp.carrid
                  WHERE sp.mandt = :clnt AND sp.carrid = :carrid
                  ORDER BY sc.mandt, sc.carrname, sp.connid;

ENDMETHOD.

 

而方法SELECT_GET_SCARR_SPFLI是一个AMDP
procedure实现,它应用select从地方的function实现着获取数据。代码如下:

METHOD select_get_scarr_spfli
       BY DATABASE PROCEDURE FOR HDB
       LANGUAGE SQLSCRIPT
       OPTIONS READ-ONLY
       USING cl_demo_amdp_functions_inpcl=>get_scarr_spfli.
  SCARR_SPFLI_TAB =
  SELECT *
         FROM "CL_DEMO_AMDP_FUNCTIONS_INPCL=>GET_SCARR_SPFLI"(
                clnt => :clnt,
                carrid => :carrid );
ENDMETHOD.

 

也可将AMDP function实现吗CDS table function。这里就是不贴示例了。

 

有关AMDP实现的视频教程:

AMDP异常

AMDP
procedure实现的不得了名前缀是CX_AMDP。这些非常且以目录CX_DYNAMIC_CHECK之下,必须以RASING显式地于AMDP
procedure实现的定义着宣称。

CX_ROOT
  |
  |–CX_DYNAMIC_CHECK
       |
       |–CX_AMDP_ERROR
           |
           |–CX_AMDP_VERSION_ERROR
           |    |
           |    |–CX_AMDP_VERSION_MISMATCH
           |
           |–CX_AMDP_CREATION_ERROR
           |    |
           |    |–CX_AMDP_CDS_CLIENT_MISMATCH
           |    |
           |    |–CX_AMDP_DBPROC_GENERATE_FAILED
           |    |
           |    |–CX_AMDP_DBPROC_CREATE_FAILED
           |    |
           |    |–CX_AMDP_NATIVE_DBCALL_FAILED
           |    |
           |    |–CX_AMDP_WRONG_DBSYS
           |
           |–CX_AMDP_EXECUTION_ERROR
           |    |
           |    |–CX_AMDP_EXECUTION_FAILED
           |    |
           |    |–CX_AMDP_IMPORT_TABLE_ERROR
           |    |
           |    |–CX_AMDP_RESULT_TABLE_ERROR
           |
           |–CX_AMDP_CONNECTION_ERROR
                |
                |–CX_AMDP_NO_CONNECTION
                |
                |–CX_AMDP_NO_CONNECTION_FOR_CALL
                |
                |–CX_AMDP_WRONG_CONNECTION

留神:AMDP
function没有好类。

工具支持

AMDP在SAP NetWeaver AS ABAP 7.40
SP05版本被给引入。只有基于Eclipse的开发工具(即ADT,版本要无小于2.19)才支撑AMDP的编纂,SAP
GUI上面的SE80是无提供编辑功能的,只能用来读代码。

有关AMDP调试的视频教程:

总结

运ABAP Managed Database Procedure(AMDP)和CDS开发,属于自上而下的ABAP
for
HANA开发方式。在使层即ABAP程序中管理数据测算逻辑与建模,激活后会见当HANA中开创相应的数据库对象。相比于原始片Database
Procedure Proxy,AMDP提供了简易的调用SQL Script等数据库语言的计。

 

参照文章:

[1] AMDP – ABAP Managed Database
Procedures

[2] ABAP Managed Database Procedures –
Introduction

[3] ABAP Development for SAP
HANA

[4] How to use AMDP Function implementation for a CDS Table Function
as a data source in CDS
views

外资料:

SAP HANA SQL Script
Reference

ABAP CDS Table
Function介绍和示范

 

相关文章